property pBlurX, pBlurY, pQuality, pStrength, pStrengthPcnt -- blur vars
property pColorR, pColorG, pColorB -- color
property pAlpha -- alpha
property pAngle -- shadow angle
property pDist -- shadow offset distance
property pKnockout, pInner, pHidden

--
-- Drop onto a sprite for a Drop Shadow visual effect on rollover.
-- Works only with Director 11.5 or newer
-- Sprite must have 32-bit color for the effect to display.
-- Ken Loge - http://diginoodles.com
--

on getPropertyDescriptionList me
  list = [:]
  addProp list, #pBlurX, [#comment: "Horizontal Blur:", #format: #integer, #default: 4, #range: [#min: 0, #max: 255]]
  addProp list, #pBlurY, [#comment: "Vertical Blur:", #format: #integer, #default: 4, #range: [#min: 0, #max: 255]]
  addProp list, #pQuality, [#comment: "Blur Quality:", #format: #integer, #default: 2, #range: [#min: 0, #max: 15]]
  addProp list, #pStrength, [#comment: "Imprint Strength:", #format: #integer, #default: 1.0, #range: [#min: 0, #max: 10]]
  addProp list, #pStrengthPcnt, [#comment: "Shadow Intensity:", #format: #integer, #default: 100, #range: [#min: 0, #max: 1000]]
  addProp list, #pColorR, [#comment: "Shadow Red Color Value:", #format: #integer, #default: 40, #range: [#min: 0, #max: 255]]
  addProp list, #pColorG, [#comment: "Shadow Green Color Value:", #format: #integer, #default: 40, #range: [#min: 0, #max: 255]]
  addProp list, #pColorB, [#comment: "Shadow Blue Color Value:", #format: #integer, #default: 40, #range: [#min: 0, #max: 255]]
  addProp list, #pAlpha, [#comment: "Shadow Alpha Transparency:", #format: #float, #default: 0.5, #range: [#min: 0, #max: 255]]
  addProp list, #pAngle, [#comment: "Shadow Angle:", #format: #integer, #default: 336, #range: [#min: 0, #max: 360]]
  addProp list, #pDist, [#comment: "Shadow Glow Distance:", #format: #integer, #default: 4, #range: [#min: -255, #max: 255]]
  addProp list, #pKnockout, [#comment: "Knockout Effect:", #format: #boolean, #default: 0]
  addProp list, #pInner, [#comment: "Inner Shadow:", #format: #boolean, #default: 0]
  addProp list, #pHidden, [#comment: "Sprite is Hidden:", #format: #boolean, #default: 0]
  return list
end

on mouseEnter me
  -- add VFX filter
  myFilter = filter(#DropShadowFilter, [#distance:pDist, #angle:pAngle, #color:color(pColorR,pColorG,pColorB), #alpha:pAlpha, #blurX:pBlurX, #blurY:pBlurY, #strength:pStrength, #quality:pQuality, #inner:pInner, #knockout:pKnockout, #hideObject: pHidden])
  sprite(me.spriteNum).filterlist.append(myFilter)
end

on mouseLeave me
  -- clear VFX filter
  sprite(me.spriteNum).filterlist.deleteAll()
end