property pWhichState -- the state of the coin (shrinking or growing)
property pSpeed -- how fast the grow/shrink happens
property pMinSize -- how small is the sprite before it gets bigger
property pNormSize -- width of sprite to begin with

--
-- Gives the simple illusion of a coin spinning.
-- Works best with round or circular artwork.
-- Ken Loge - http://diginoodles.com
--

on beginSprite me
  pWhichState = "shrink"
  pNormSize = sprite(me.spriteNum).width
end

on getPropertyDescriptionList me
  list = [:]
  addProp list, #pSpeed, [#comment: "Speed of Change:", #format: #integer, #default: "5", #range: [#min: 0, #max: 20]]
  addProp list, #pMinSize, [#comment: "Minimum Size to Expand:", #format: #integer, #default: "5", #range: [#min: 0, #max: 100]]
  return list
end

on exitFrame me
  case pWhichState of
    "shrink": shrinkCoin(me)
    "grow": growCoin(me)
  end case
end

on shrinkCoin me
  sprite(me.spriteNum).width = sprite(me.spriteNum).width - pSpeed
  if sprite(me.spriteNum).width < pMinSize then
    pWhichState = "grow"
  end if
end

on growCoin me
  sprite(me.spriteNum).width = sprite(me.spriteNum).width + pSpeed
  if sprite(me.spriteNum).width > pNormSize then
    pWhichState = "shrink"
  end if
end